OBO Flat File Format Syntax and Semantics
and Mapping to OWL Web Ontology Language

Abstract

1 Introduction

This document suggests a formalisation (using BNF) of the OBO Flat File Format Specification, version 1.2 (which we will refer to from now on as OBO), and a semantics for (part of) the language defined via a translation to the OWL DL abstract syntax (which is a decidable fragment of FOL corresponding to the Description Logic SHOIN). The objectives are:

• To identify and help to resolve any ambiguities in OBO.
• To clarify/define the semantics of OBO via a mapping to OWL DL.

2 OBO Syntax

This section suggests a BNF style grammar for OBO. This helps to make the structure a little more precise and allows any ambiguities and/or misunderstandings to be clarified. It is also allows the grammar to be automatically checked (e.g., for ambiguities) and a parser to be generated.

The grammar is presented in the standard BNF notation. Nonterminal symbols are denoted in bold (e.g., stanza), terminal symbols are written in single quotes (e.g. 'Term', zero or more instances of a symbol is denoted with curly braces (e.g., { stanza }), alternative productions are denoted with the vertical bar (e.g., term-stanza | typedef-stanza), and zero ore one instances of a symbol are denoted with square brackets (e.g., [ 'is_anonymous: true' ]).

Several simplifications have been made in the following grammar: details relating to XML syntax have been ignored, and details of some of the annotation tags are omitted. Angle brackets are used to denote parts of the specification which are nonterminal, but which are not further defined here (e.g., < saved-by >).

The OBO specification did not seem to be completely clear with respect to some details of syntax and semantics. Some of these have been resolved by communications from the OBO developers, in particular Chris Mungall:

• An OBO file may include zero stanzas (e.g., a file of standard idspaces in obo format).
• In OBO, name is purely documentary (like RDF labels), and the id is what is used to refer to a term in other stanzas (although it is strongly encouraged, and may even be enforced, that names uniquely identify a class, relation or instance within an ontology or OBO namespace).
• The sets of Typedef (relationship) IDs, Term IDs and Instance IDs must be pairwise disjoint.
• The minimum and maximum number of occurrences of each tag type in a given stanza has now been explicated. For example, an OBO Typedef stanza may contain at most one of each of the following tags: range, domain, inverse, transover and comment.
• OBO may adopt an OWL style import semantics in order to avoid potential problems with the existing "append document at parse time" semantics in case of cyclical imports statements.
• The not_necessary and inverse_necessary modifiers are likely to be deprecated, with their meaning being encoded in the semantics of relevant relations. Future versions of OBO may allow existential and universally quantified relationships to be distinguished.
• The relationship tag may be banned in Typedef stanzas as its meaning there is not clear.

• The derived modifier could lead to some strange situations. E.g., there could be two facts such that either can be derived, but not both. I isn't clear what the status of an OBO ontology would be if derived modifiers are "inconsistent". (This will be clarified in future versions of OBO.)
• Is there any restriction on mixing of datatypes and classes, e.g., in intersection and union?
• Are cardinality tags meant to signify a qualified or unqualified restriction?
• Are OBO built-in objects semantically meaningful? They are potentially problematical (higher order) and don't seem obviously useful.
• OBO intersection and union tags specify necessary and sufficient conditions, but does this extend to the whole stanza? (I assume not, as this wouldn't make sense in case both intersection and union occurred in the same stanza.)
• Do the "false" cases of the relation qualifiers (is_symmetric etc.) signify "not necessarily true" or "necessarily false"?
• What is meant by "If a particular relationship tag has a "true" trailing qualifier then the inverse applies at the term level."?

2.1 OBO File Structure

An OBO file consists of a header followed by zero or more stanzas.

OBO-Doc := header { stanza }

2.2 OBO Header

The header consists of a number of tag-value pairs, most of which we will ignore for the time being. Many of these (e.g., <remark> could clearly be treated as annotations; others (e.g., <default-namespace> correspond to parts of an XML document preamble.

header :=
   <format-version>
   [ <data-version> ]
   [ <date> ]
   [ <saved-by> ]
   [ <auto-generated-by> ]
   [ <subsetdef> ]
   { import }
   { <synonymtypedef> }
   { <idspace> }
   [ <default-relationship-id> ]
   { <idmapping> }
   [ <remark> ]
import := 'import:' <URL>
stanza := term-stanza | typedef-stanza | instance-stanza

2.3 Term Stanzas

Term stanzas introduce and define the meaning of terms (AKA concepts, classes and unary predicates).

term-stanza :=
   '[Term]'
   termid-TVP
   'name:'<string>
   [ <namespace> ]
   { <alt_id> }
   [ <def> ]
   [ <comment> ]
   { <subset> }
   { <synonym> }
   { <xref> }
   { isa-TVP }
   { intersection-TVP }
   { union-TVP }
   { disjoint-TVP }
   { relationship-TVP }
   [ <is_obsolete> ]
   [ <replaced_by> ]
   { <consider> }

termid-TVP :=
   'id:' term-id
   [ 'is_anonymous: true' ]
term-id := <string>

isa-TVP :=
   'is_a:' term-id
   [ 'namespace=' <namespace-id> ]
   [ 'derived=true' | 'derived=false' ]

intersection-TVP :=
   'intersection_of:' termOrRestr
   [ 'namespace=' <namespace-id> ]
termOrRestr := term-id | restriction
restriction := relationship-id term-id
relationship-id := <string>

union-TVP :=
   'union_of:' termOrRestr
   [ 'namespace=' <namespace-id> ]

disjoint-TVP :=
   'disjoint_from:' term-id
   [ 'namespace=' <namespace-id> ]
   [ 'derived=true' | 'derived=false' ]

relationship-TVP :=
   'relationship:' restriction
   [ 'not_necessary=true' | 'not_necessary=false' ]
   [ 'inverse_necessary=true' | 'inverse_necessary=false' ]
   [ 'cardinality=' <non-neg-int> ]
   [ 'maxCardinality=' <non-neg-int> ]
   [ 'minCardinality=' <non-neg-int> ]

2.4 Typedef Stanzas

Typedef stanzas introduce and define the meaning of relations (AKA roles, properties and binary predicates).

typedef-stanza :=
   '[Typedef]'
   typedef-TVP
   'name:'<string>
   [ <namespace> ]
   { <alt_id> }
   [ <def> ]
   [ <comment> ]
   { <subset> }
   { <synonym> }
   { <xref> }
   [ domain-TVP ]
   [ range-TVP ]
   { meta-property-TVP }
   { r-isa-TVP }
   { r-intersection-TVP }
   [ inverse-TVP ]
   [ transover-TVP ]
   { relationship-TVP }
   [ 'is_metadata_tag:true' | 'is_metadata_tag:false' ]
   [ <is_obsolete> ]
   [ <replaced_by> ]
   { <consider> }

typedefid-TVP :=
   'id:' relationship-id
   [ 'is_anonymous: true' ]

domain-TVP := 'domain:' termOrReserved
termOrReserved := term-id | <reserved-id>

range-TVP := 'range:' termOrReserved

meta-property-TVP :=
   'is_anti_symmetric:true' | 'is_anti_symmetric:false' |
   'is_cyclic:true' | 'is_cyclic:false' |
   'is_reflexive:true' | 'is_reflexive:false' |
   'is_symmetric:true' | 'is_symmetric:false' |
   'is_transitive:true' | 'is_transitive:false'

r-isa-TVP := 'is_a:' relationship-id [ isa-mlist ]
isa-mlist := '{' isa-modifier { ',' isa-modifier } '}'
isa-modifier := namespace-mod | derived-mod
namespace-mod := 'namespace=' namespace-id
derived-mod := 'derived=true' | 'derived=false'

r-intersection-TVP :=
   'intersection_of:' relationship-id
   [ 'namespace=' <namespace-id> ]

inverse-TVP := 'inverse:' relationship-id

transover-TVP := 'transitive_over:' relationship-id

2.5 Instance Stanzas

Instance stanzas introduce and define the meaning of instances (AKA individuals, individual names, constants).

instance-stanza :=
   '[Instance]'
   instanceid-TVP
   'name:'<string>
   [ <namespace>]
   { <alt_id> }
   [ <comment> ]
   { <synonym> }
   { <xref> }
   'instance_of:' term-id { 'instance_of:' term-id }
   { p-obj-value-TVP | p-data-value-TVP }
   [ <is_obsolete> ]
   [ <replaced_by> ]
   { <consider> }

instanceid-TVP :=
   'id:' instance-id
   [ 'is_anonymous: true' ]

p-obj-value-TVP := 'property_value:' relationship-id instance-id

p-data-value-TVP := 'property_value:' relationship-id '"' <string> '"' <XML-Schema-datatype>

3 OBO Semantics

This section defines the semantics of (a large subset of) OBO via a mapping to OWL DL. The mapping could also be used to specify a translation procedure and/or an interface to OWL tools (such as OWL reasoners).

A number of simplifying assumptions are made in order to improve readability:

• Syntax related declarations (namespace, etc.) and "annotations" (comment, etc.) are largely ignored.
• OBO identifiers/names are translated "as is".
• Only cardinality relationship modifiers are considered, and these are treaded as unqualified (although they could be translated into qualified cardinality restrictions in OWL 1.1).
• Reflexive, antisymmetric and transitive_over relation qualifying tags are treated as annotations in OWL (although they could be translated into the relevant property axioms in OWL 1.1).
• The cyclic relation qualifying tag is treated as an annotation in OWL.
• The "false" cases of relation qualifying tags are ignored (although they could be translated into OWL "facts" that assert counter-examples, if this is deemed to be appropriate).
• It is assumed that relations will be translated into OWL datatype properties if the either the Typedef stanza specifies a range that is an XML datatype or if some super relation was translated into a datatype property.
• Intersections in Typedef stanzas are treated in the same way as isa, i.e., as a necessary condition rather than a necessary and sufficient condition.
• Relationships in Typedef stanzas are ignored due to uncertainty as to the intended semantics.

The translation is defined using a translation function T which translates (a fragment of) OBO into OWL DL. The definition of T is often recursive, but it will eventually "ground out" in (a fragment of) OWL DL.